Ch04_기본수식과 셀참조(1)

티스토리 뷰

강의실/엑셀로 데이터마스터하기

Ch04_기본수식과 셀참조(1)

jsBae 2026. 9. 17. 23:34

엑셀에서 데이터를 입력하는 것만으로는 업무에 필요한 결과를 얻기 어렵다. 입력된 데이터를 계산하고 분석하려면 수식과 함수를 사용하여야 한다. 특히 수식을 다른 셀로 복사할 때 셀 주소가 어떻게 변하는지를 이해하는 것은 엑셀 활용의 핵심이다.

이 장에서는 수식의 기본 구조부터 상대 참조, 절대 참조, 혼합 참조까지 단계적으로 학습한다. 또한 실무형 종합예제를 통하여 여러 종류의 셀 참조를 하나의 표에서 적용해 본다.

학습목표

- 엑셀 수식의 기본 구조와 연산 순서를 설명할 수 있다.
- 산술 연산자와 비교 연산자를 사용하여 수식을 작성할 수 있다.
- 수식을 입력하고 수정하며 다른 셀로 복사할 수 있다.
- 상대 참조, 절대 참조, 혼합 참조의 차이를 설명할 수 있다.
- 수식 입력 과정에서 발생하는 주요 오류를 확인하고 수정할 수 있다.

ch03_수식입력하기.xlsx

0.01MB

Section01. 수식의 이해

수식이란?

수식은 워크시트에 입력된 숫자나 셀의 값을 이용하여 계산 결과를 구하는 표현식이다.
엑셀에서 수식은 반드시 등호 =로 시작한다.

=10+20

위 수식을 셀에 입력하면 셀에는 수식 자체가 아니라 계산 결과인 30이 표시된다. 엑셀 수식에서는 숫자를 직접 입력할 수도 있지만, 일반적으로 셀 주소를 참조하여 계산한다.

=A2+B2

이 수식은 A2 셀의 값과 B2 셀의 값을 더한다는 의미이다. 셀 주소를 사용하는 이유는 원본 데이터가 변경되었을 때 계산 결과가 자동으로 다시 계산되기 때문이다. 예를 들어 A2 셀에 100, B2 셀에 200이 입력되어 있다면 =A2+B2의 결과는 300이다. 이후 A2 셀의 값을 150으로 변경하면 수식의 결과도 자동으로 350으로 변경된다.

수식의 기본 구성 요소

엑셀 수식은 다음 요소로 구성된다.

=(A2+B2)*C2

=: 수식의 시작
A2, B2, C2: 셀 참조
+, *: 연산자
( ): 계산 순서 지정
숫자 또는 문자: 상수
SUM, AVERAGE: 함수

다음 수식은 셀 참조, 연산자, 숫자 상수를 함께 사용한 예이다.

=A2*0.1

A2 셀 값의 10%를 계산한다.

=A2*(1-B2)

A2 셀의 금액에서 B2 셀에 입력된 할인율만큼 차감한 금액을 계산한다.

키보드로 수식 입력하기

결과를 표시할 셀을 선택한다.
등호 =를 입력한다.
셀 주소와 연산자를 입력한다.
Enter를 누른다.

예를 들어 A2 셀의 단가와 B2 셀의 수량을 곱하여 C2 셀에서 금액을 계산하려면 다음과 같이 입력한다.

=A2*B2

--- 수식 수정하기

방법 1: 수식 입력줄 이용

수식이 입력된 셀을 선택한다.
수식 입력줄에서 수식을 수정한다.
Enter를 누른다.

방법 2: 셀을 두 번 클릭

수식이 입력된 셀을 두 번 클릭한다.
셀 내부에서 수식을 수정한다.
Enter를 누른다.

방법 3: F2 키 이용

수식이 입력된 셀을 선택한다.
F2 키를 누른다.
수식을 수정한다.
Enter를 누른다.

수식 수정을 취소하려면 Esc를 누른다.

엑셀의 연산자

--- 산술 연산자

산술 연산자는 숫자를 계산할 때 사용한다.

연산자	의미	수식	결과
+	더하기	=10+5	15
-	빼기	=10-5	5
*	곱하기	=10*5	50
/	나누기	=10/5	2
^	거듭제곱	=10^2	100
%	백분율	=100*10%	10

엑셀에서는 곱하기 기호로 ×가 아니라 별표 *를 사용하고, 나누기 기호로 ÷가 아니라 슬래시 /를 사용한다.

--- 비교 연산자

비교 연산자는 두 값의 관계를 비교한다. 계산 결과는 TRUE 또는 FALSE로 표시된다.

=	같다	=10=10	TRUE
>	크다	=10>5	TRUE
<	작다	=10<5	FALSE
>=	크거나 같다	=10>=10	TRUE
<=	작거나 같다	=10<=5	FALSE
<>	같지 않다	=10<>5	TRUE

비교 연산자는 IF, COUNTIF, SUMIF 등의 함수에서 조건을 지정할 때 자주 사용한다.

=A2>=60

A2 셀의 값이 60 이상이면 TRUE, 그렇지 않으면 FALSE를 반환한다.

--- 텍스트 연결 연산자

앰퍼샌드 &는 여러 셀의 문자나 숫자를 하나의 문자열로 연결한다. A2 셀에 홍길동, B2 셀에 학생이 입력된 경우 다음과 같이 작성할 수 있다.

=A2&B2

중간에 공백을 넣으려면 큰따옴표를 사용한다.

=A2&" "&B2

예제)

=A2&"님의 총점은 "&B2&"점입니다."

실습: 연산자를 이용하여 수식 작성

먼저 다음 파일을 컴퓨터에 내려받는다.

1. 총판매량 계산하기

총판매량은 상반기 판매량과 하반기 판매량을 더하여 계산한다.

F5 셀을 선택하고 다음 수식을 입력한다.

=D5+E5

Enter를 누른 후 F5 셀의 채우기 핸들을 F14 셀까지 드래그한다.
첫 번째 상품인 무선 마우스의 총판매량은 다음과 같다. ( 540+710=1,250)
수식을 아래로 복사하면 셀 주소가 각 행에 맞게 자동으로 변경된다.

2. 평균판매량 계산하기

평균판매량은 총판매량을 판매 기간의 수인 2로 나누어 계산한다.
G5 셀에 다음 수식을 입력한다.
수식을 G14 셀까지 자동 채우기한다.

=F5/2

3. 목표 달성 여부 확인하기

총판매량이 목표량 이상인지 비교하여 목표 달성 여부를 판단한다.

H5 셀에 다음 수식을 입력한다.

=F5>=C5

수식을 H14 셀까지 자동 채우기한다.
총판매량이 목표량 이상이면 TRUE, 총판매량이 목표량보다 적으면 FALSE
비교 연산자 >=는 왼쪽 값이 오른쪽 값보다 크거나 같은지를 판단한다.

4. 초과 달성량 계산하기

목표량과 실제 판매량의 차이를 계산한다.

I5 셀에 다음 수식을 입력한다.

=F5-C5

수식을 I14 셀까지 자동 채우기한다.

계산 결과는 다음과 같이 해석한다.

양수: 목표량을 초과함
0: 목표량과 판매량이 같음
음수: 목표량에 미달함

Section2. 자동 합계 도구로 수식입력 - 전체 총판매량 계산하기

자동 합계 도구

자동 합계(Σ)는 선택한 셀 주변의 숫자 범위를 자동으로 인식하여 합계 수식을 입력하는 도구이다. 숫자를 일일이 더하거나 SUM 함수를 직접 입력하지 않아도 빠르게 합계를 계산할 수 있다.

자동 합계 도구는 다음 위치에서 사용할 수 있다.

홈 탭 → 편집 그룹 → 자동 합계(Σ)

단축키는 다음과 같다.

Alt + =

자동 합계를 실행한 후에는 엑셀이 선택한 계산 범위가 정확한지 확인하고 Enter를 눌러 수식을 완성한다. 자동 합계 도구의 펼침 단추에서는 합계뿐만 아니라 평균, 숫자 개수, 최댓값, 최솟값도 계산할 수 있다.

--- 전체 상품의 총판매량은 SUM 함수를 사용하여 계산할 수 있다.

이번에는 수식을 직접 입력하지 않고 리본 메뉴의 자동 합계 도구를 사용한다.

자동 합계 실행하기

전체 총판매량을 표시할 M4 셀을 선택한다.
리본 메뉴에서 홈 탭을 선택한다.
편집 그룹의 자동 합계(Σ) 단추를 클릭한다.
엑셀이 제안한 합계 범위를 확인한다.
범위가 올바르지 않으면 마우스로 F5:F14 범위를 다시 지정한다.
Enter를 눌러 수식을 완성한다.

수식 입력줄에는 다음과 같이 표시된다.

SUM: 지정한 숫자의 합계를 구하는 함수
F5:F14: 첫 번째 상품부터 마지막 상품까지의 총판매량 범위
: : 시작 셀부터 마지막 셀까지의 연속된 범위를 의미하는 참조 연산자

자동 합계 단축키를 사용하면 같은 작업을 빠르게 수행할 수 있다.

Alt + =

자동 합계가 선택한 범위를 항상 정확하게 판단하는 것은 아니다. 수식을 확정하기 전에 점선으로 표시된 계산 범위가 F5:F14인지 반드시 확인한다.

--- 함수의 자동합계를 이용하여 평균판매량, 상품개수, 최고판매량, 최저판매량을 계산해 보자.

평균판매량- AVERAGE 함수( 지정한 범위에 입력된 숫자의 평균을 구한다.)

상품별 총판매량의 평균을 계산한 값이다. AVERAGE 함수를 사용한다.

=AVERAGE(F5:F14)

상품 개수- COUNT 함수

지정한 범위에서 숫자가 입력된 셀의 개수를 구한다. 문자와 빈 셀은 제외한다.
총판매량이 입력된 숫자 셀의 개수를 계산한다. COUNT 함수를 사용한다.

=COUNT(F5:F14)

최고판매량- MAX 함수

상품별 총판매량 중 가장 큰 값을 구한다. MAX 함수를 사용한다.

=MAX(F5:F14)

최저판매량- MIN 함수

상품별 총판매량 중 가장 작은 값을 구한다. MIN 함수를 사용한다.

=MIN(F5:F14)

Section03. 셀 참조 이해하기

엑셀의 수식은 숫자를 직접 입력하는 대신 셀의 위치를 참조하여 계산할 수 있다. 이를 셀 참조(Cell Reference)라고 한다. 셀 참조를 사용하면 원본 데이터가 변경될 때 수식의 결과도 자동으로 다시 계산된다.

예를 들어 상반기 판매량이 D5 셀, 하반기 판매량이 E5 셀에 입력되어 있다면 총판매량은 다음과 같이 계산한다.

=D5+E5

D5 또는 E5의 값이 변경되면 F5의 총판매량도 자동으로 변경된다.

1. 셀 주소의 구성

셀 주소는 열 문자와 행 번호의 조합으로 구성된다.

D5

D: D열
5: 5행
D5: D열과 5행이 만나는 셀

셀 참조[F4]는 수식을 복사할 때 주소가 변하는 방식에 따라 상대 참조, 절대 참조, 혼합 참조로 구분한다.

참조	표시	특징
상대 참조	A1	수식을 복사하면 열과 행이 변경됨
절대 참조	$A$1	수식을 복사해도 열과 행이 고정됨
혼합 참조	$A1	열만 고정되고 행은 변경됨
혼합 참조	A$1	행만 고정되고 열은 변경됨

상대 참조: 상대 참조는 수식을 다른 셀로 복사할 때 복사된 위치에 따라 셀 주소가 자동으로 변경되는 참조 방식이다.
절대 참조: 절대 참조는 수식을 다른 셀로 복사하여도 참조하는 셀 주소가 변경되지 않도록 고정하는 방식이다.
열 문자와 행 번호 앞에 달러 기호 $를 붙인다.
$기호는 직접 입력해도 되지만 F4를 이용해 셀 주소에 붙일 수 있다.

열 문자와 행 번호 앞에 달러 기호 $를 붙인다.

=$A$1

예를 들어 M4 셀에 전체 상품의 평균판매량이 입력되어 있고, 각 상품의 판매량이 전체 평균 이상인지 비교한다고 가정한다.
H5 셀에 다음 수식을 입력한다.

=F5>=$M$4

--- 우수상품 여부 확인하기

상품별 판매실적 데이터에서 평균판매량을 기준으로 그 이상 판배 된 것을 우수 상품으로 판정하는 수식을 작성 해 보자.

상대참조로 비교하는 수식( =F5>=M5 )을 작성하며, 첫 행은 제대로 판별이 된다.
그러나 자동채우기를 하였을 경우, 기준이 되는 평균판매량의 참조도 하단으로 같이 이동하는 것을 알 수 있다.
따라서, 평균판매량개수(M5)의 경우는 절대참조를 하여 변하지 않게 한다.

절대참조로 변경하기.

셀입력 활성화(F2)하여 커서를 M5옆에 두고, F4를 클릭한다.
F4클릭 시 절대, 혼합으로 변경되는 것을 확인할 수 있다.
마지막 행에서 확인할 때 평균판매량 참조는 변화지 않는 것을 확인 할 수 있다.

--- 혼합 참조를 학습 - 실습: 상품별 할인 가격표 완성하기

혼합 참조를 이용한 수식으로 할인율에 따른 상품별 가격을 계산 해 보자.

1. 원화를 달러로 환산하기

환율은 K4 셀의 1,400원을 모든 상품에 공통으로 적용한다. 달러 가격은 원화 가격을 환율로 나누어 계산한다.

C5 셀에 다음 수식을 입력한다.

=D5/$K$4

수식을 C14 셀까지 자동 채우기한다.

D5: 상품의 원화 정가
$K$4: 모든 상품에 동일하게 적용할 환율
/: 나누기 연산자

환율 셀은 수식을 복사하여도 변경되면 안 되므로 절대 참조를 사용한다.

무선 마우스의 달러 가격은 다음과 같다.
28,000÷1,400=2028,000\div1,400=20
따라서 C5 셀에는 20달러가 표시된다.

2. 10% 할인 가격 계산하기

10% 할인 가격은 정가의 90%에 해당한다. E5 셀에 다음 수식을 입력한다.

=$D5*(1-E$4)

$D5: 정가가 입력된 D열을 고정한다.
E$4: 할인율이 입력된 4행을 고정한다.
1-E$4: 할인 후 적용할 가격 비율을 계산한다.

무선 마우스의 10% 할인 가격은 다음과 같다.
28,000× (1−10%)=25,200

E5:I14까지 선택 후,
=$D5*(1-E$4) 작성한다.
이때 D5~D14까지의 정가열은 참조하기에, 열($D)은 고정이며, 행만 변하는 혼합참조를 사용한다.
또한, 할인율은 열로 변하기 때문에 E4~I4까지 참조하기 위해, 행($4) 은 고정이고, 열(E~I)은 변하는 혼합참조를 사용한다.
수식을 작성하고, Ctrl+enter를 클릭하면 한번에 수식이 적용된다.

표시 형식 적용하기

이제 셀서식을 이용하여 표시형식을 지정 해 보자.

C5:C14 범위: 달러 통화 또는 사용자 지정 서식

$#,##0.00

D5:I14 범위: 원화 표시 형식

#,##0"원"

공지사항

최근에 올라온 글

최근에 달린 댓글

Total

Today

Yesterday

링크

TAG more

« 2026/09 »
일	월	화	수	목	금	토
		1	2	3	4	5
6	7	8	9	10	11	12
13	14	15	16	17	18	19
20	21	22	23	24	25	26
27	28	29	30

글 보관함

multiking

티스토리 뷰